ASP Formular-Datenübergabe

H

Hansenstgt

Guest
Ich habe ein Kontaktformular in einem Microsoft-Account bei Schlund & Partner, und probiere gerade, aus den Formularfeldern eine Email zu erzeugen, und habe nun folgendes Problem, das mail.asp verschickt auch ein Mail aber ohne Formulardaten.

Es erscheint nur der Text

False


Hier das script

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D"
NAME="CDO for Windows 2000 Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4"
NAME="ADODB Type Library" -->
<!--Durch die obigen METADATA werden die CDO Konstanten bekannt gemacht,
wie z.B. cdoSendUsingMethod-->
<html>
<body>
<%
Dim strFrom, strTo, strSubject, strBody
Dim objMessage, objConfig
strFrom = "info@test.de" 'Absender
strTo = "info@test.de" 'Empfänger
strSubject = "Kontakt" 'Mail Subject
strBody = strBody & strBody = "Vorname: " & Request.Form("Vorname") & vbCRLF
strBody = strBody & strBody = "Name: " & Request.Form("Name") & vbCRLF
strBody = strBody & strBody = "Firma: " & Request.Form("Firma") & vbCRLF
strBody = strBody & strBody = "Strasse: " & Request.Form("Strasse") & vbCRLF
strBody = strBody & strBody = "Ort: " & Request.Form("Ort") & vbCRLF
strBody = strBody & strBody = "Telefon: " & Request.Form("Telefon") & vbCRLF
strBody = strBody & strBody = "Fax: " & Request.Form("Fax") & vbCRLF
strBody = strBody & strBody = "Email: " & Request.Form("Email") & vbCRLF

'Erzeugen des Email Server Objects
Set objMessage = CreateObject("CDO.Message")
Set objConfig = CreateObject("CDO.Configuration")

'Hier wird festgelegt wie die Mails versendet werden (lokal oder extern)
'Bitte immer externen Versand angeben, da eine lokaler Versand nicht
'möglich ist.
objConfig.Fields(cdoSendUsingMethod) = cdoSendUsingPort

'Ausgehender SMTP Server mit SMTP-Auth
objConfig.Fields(cdoSMTPServer) = "mxbulk.kundenserver.de"

'SMTP Port
objConfig.Fields(cdoSMTPServerPort) = 25
'Klartext Authentifizierung
objConfig.Fields(cdoSMTPAuthenticate) = cdoBasic

'Accountname
objConfig.Fields(cdoSendUserName) = ""

'Passwort
objConfig.Fields(cdoSendPassword) = ""

objConfig.Fields.Update

Set objMessage.Configuration = objConfig
objMessage.To = strTo
objMessage.From = strFrom
objMessage.Subject = strSubject
objMessage.TextBody = strBody 'Plain Text Modus

On Error Resume Next
objMessage.Send

If Err.Number = "0" Then
Response.Write("Die Nachricht wurde versendet!")
Else
Response.Write("Waehrend des Versendens ist " & _
"ein Fehler aufgetreten.")
response.write Err.Number & " " & Err.Description
Err.Number = "0"
End If
%>
</body>

wer kann mir da weiterhelfen.

grüsse Hansen
 
"False" ist komplet richtig, denn:

CODE strBody = strBody & strBody = "Email: " & Request.Form("Email") & vbCRLF

ergibt


CODE strBody = False

weil


CODE strBody & strBody = "Email: " & Request.Form("Email") & vbCRLF

False ergibt.

Dir ist wohl was beim kopieren schief gelaufen, mach ein "Replace all"
mit
CODE strBody & strBody = " ersetzen durch
CODE strBody & ", des will help a step.

Greez
 
Sie müssen sich einloggen oder registrieren, um hier antworten zu können.
Zurück
Oben